• Ichigojam
• puzzle

NEW

1 '### "LONGCAT" DATA ###
2 Z=#C03:Y=#700:U=0
3 X=0:IF PEEK(Z)!=39 GOTO 9
4 X=X-1:W=PEEK(Z-X)
5 W=W-41-W/32*6:IF W<0 GOTO 8
6 V=V<<6+W:POKE Y,V>>(X*2&7)
7 Y=Y+(X&3<3):U=U^W:GOTO 4
8 IF U LIST PEEK(Z-3):END
9 Z=Z+PEEK(Z-1)+4:W=PEEK(Z-3)
10 IF W GOTO 3 ELSE LRUN 1
11 'ttbzzvqZzzzbaTzzzuLzzzzz2
12 'zzzzzzwnTrzzzzxzTrDyzzzzw
13 'zzzzTrxzzzxzTzzzyKCB6zhXJ
14 'K/DsEqc0RI8X/FMfI//pU2I/t
15 'VOJ//2RG9/500EcN/NE//HJEE
16 'U//HgI/2/V0U/09E703260//P
17 '/dE15E7/4/UtccvU///HB1YUu
18 '/E/1//k////QQ8/4j//J4p40U
19 '/U/65095U//MZsU5n/131//Wu
20 '//247/7U7//KE1:W/E01E//44
21 '/E22//U////4M4Z////0/0//B
22 '///5Q10E9V/0xE/F317/3kTk9
23 '/7SNE/1830aUZA/Q/eF5Ee6Fn
24 '/YO31418E/13I/317/Q/F1/0o
25 'o//73/3//HEM///:gFU0/kk/k
26 'REUZ0VU0//g120QU0lU313Ecn
27 'UBQ2/mP30Y/:66e/1MFG:F/7E
28 'w/5/30Y//G133E78//A///M75
29 '/EP6k/1WUV///E/B

SAVE 0

NEW

1 '### "LONGCAT" MAIN ###
2 VIDEO 5:CLS:?:?:?" (#E3)(#E2)(#E2)(#E2)(#E2)(#E0)":?
3 ?"Long Cat";:BEEP 8,9:Q=9:X=6
4 Y=2:GSB 27:IF INKEY()!=10CONT
5 VIDEO 3:?CHR$(4):R=1
6 BEEP 20:COPY #901,#900,159
7 LC 0,10:?"Level ";R:U=0:E=0
8 S=7+(R=50):A=#6E8+R*7:G=0
9 IF R<32 S=6:A=#708+R*6:G=1
10 I=1+G:IF R<18 S=5:A=#72C+R*4
11 J=4+G:D=PEEK(A):C=D&15:B=16
12 IF B=256 A=A+1:D=PEEK(A):B=1
13 Z=D&B:IF!Z LC J,I:?" ":E=E+1
14 IF Z C=C-1:IF !C X=J:Y=I
15 J=J+1:IF J=4+G+S J=J-S:I=I+1
16 B=B*2:IF I<=G+S GOTO 12
17 K=INKEY():V=(K=29)-(K=28)
18 W=(K=31)-(K=30):IF K=10GOTO6
19 GSB 27:Z=V+W*2-U:T=(Z+455)/2
20 IF SCR(X+V,Y+W)!=32 GOTO 17
21 E=E-1:IF!U T=T^1-(V>0)*2
22 LC X,Y:U=Z+U:IF!Z T=226+!V*3
23 ?CHR$(T):IF!E R=R+1:BEEP4,20
24 X=X+V:Y=Y+W:IF R<=50 GOTO 19
25 LC 0,10:?"Congratulations"
26 GSB 27:Q=Q>0:CONT
27 LC X,Y:?CHR$(#E0+!Q):WAIT 5
28 Q=Q-1+(RND(36)+24)*!Q:RTN

SAVE 1

LRUN 0

Kidspod運営チーム2022/03/29 09:55:15

お、おもしろい……。シンプルながらこのパズルはハマる……。ネコのビジュアルもかわいいですね。何もしないとピョコピョコとまばたきしているところなんか、芸が細かくてお見事です。

Pagetop