Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2020/12/03 08:10:14

MixJuice GET URL : kidspod.club/mj/1037

Last One

いわゆる「ボール・ソリティア」と呼ばれるパズルゲームです。
盤面に複数の球が配置されているので、スクリーンショットの2枚目に示したルールで取り除いていき、最後の一個を盤の中央に残した状態にすればクリアとなります。
ボードの種類は2種類(正方マス/六角マス)あり、それぞれ40パターンずつ問題を用意しました。

ゲームを開始すると、盤面の種類とパターン番号を聞かれますので、キーボードから入力します。
矢印キーでカーソルを移動します。
スペースキーで、まず動かす玉を選択、次に飛び越える(取り除く)玉を選択します。
エンターキーを押すと、盤面を初期状態に戻せます。

  • 1
  • 2
  • 3
  • 4
  • 5
  • 1
  • 2
  • 3
  • 4
  • 5

SOURCE CODE

NEW

1 '### "LASTONE" DATA ###
2 Z=#C03:Y=#700:U=0
3 X=0:IF PEEK(Z)!=39 GOTO 9
4 X=X-1:W=PEEK(Z-X)
5 W=W-41-W/32*6:IF W<0 GOTO 8
6 V=V<<6+W:POKE Y,V>>(X*2&7)
7 Y=Y+(X&3<3):U=U^W:GOTO 4
8 IF U LIST PEEK(Z-3):END
9 Z=Z+PEEK(Z-1)+4:W=PEEK(Z-3)
10 IF W GOTO 3 ELSE LRUN 1
11 '//////33//U/////E1/E3//7i
12 '0/A/////A22Uk////////kwT1
13 'DnxzTk2/wDXwxDfqTrwzDlcBV
14 '/k2uwiH3W22///0yDVsyRi8/2
15 '2wzjvy2oyjME/U//7/k0/0/6P
16 'UE//n/M/U/o0/11AMk//UiA2f
17 '/8724///kTY0//6y3AT53G/Sh
18 'M0nc523iq/nl/025kk0EjqAWv
19 '/ALbik0zzEYzlkQ/q8tX1827E
20 'RXxKXD7Q/ALaCqeGYZcsVIAt0
21 'JWpdpOcDsOic6j3eY3zZYm/zG
22 'aFq/nySv/:Dm6026xkT/KhAk7
23 'iixD/L2SZU1GvyyH7Beq1DrOw
24 'hrtlLjEQiiyDyDbSxlHEKCJfq
25 '8rCR1GX4lvZIQ7CJo8y2O45z8
26 '1lLJzsyEq2DtxyXTxlRaVa3M7
27 'Dw9Dy54IAnknksONJw2qsd19h
28 'wvxULjAMpTzjOpShOkYxFHKy8
29 'pCV6hHFxFHRfbjJOAANhhaLI/
30 'jteNcuSjIAnzBxzaJH8qP5rQo
31 'qQiCiyMkrjwvXiCsrrBhrPfjS
32 'vfjyPKnzzrzxDqvyyrjzzzvzf
33 'rzzzxk4

SAVE 0

NEW

10 '### "LASTONE" MAIN ###
20 @I:CLS:C="(#E0)(#E1)(#E2)(#E3)(#E4)(#E5)(#E6)(#E7)"
30 INPUT"TYPE(0=QUAD/1=HEX):",M
40 INPUT"PATTERN(1-40):",R
50 IF M<0||M>1||R<1||R>40GOTO@I
60 @P:P=#748+R*8+M*4:Q=M:L=0
70 BEEP 24:FOR I=0 TO 6:Y=I*2+6
80 K=3-M+(ABS(I-3)<M+2)*4-I%2*M
90 X=14-K:FOR J=1 TO K:X=X+2
100 Z=PEEK(P)>>Q&1:L=L+Z:A=Z*4
110 GSB@C:Q=(Q+1)%8:P=P+!Q:NEXT
120 NEXT:P=15:Q=12:K=0:CLK
130 @L:B=INKEY():IF B=10 GOTO@P
140 W=(B=31)-(B=30):Y=Q+W*2
150 V=(B=29)-(B=28):X=P+V*2+W*M
160 IF SCR(X,Y) P=X:Q=Y
170 V=P-T:W=Q-U:S=SCR(P,Q)
180 IF K&&ABS(V)+ABS(W)>3 K=0
190 IF B=32 GSB@S
200 IF K LC T+1,U-1:?"(#E9)"
210 LC P,Q:?"(#E8)":WAIT 2
220 IF K LC T+1,U-1:?"(#E5)"
230 LC P,Q:?CHR$(S):IF L GOTO@L
240 LC 13,13:?"CLEAR!":R=R%40+1
250 PLAY"L32O5GB<DFA8":WAIT 120
260 LC 14,1:?R;" ":GOTO@P
270 @S:IF S!=#E6 K=0:RTN
280 IF!K BEEP 7:K=1:T=P:U=Q:RTN
290 X=T+V*2:Y=U+W*2:Z=SCR(X,Y)
300 K=0:IF Z!=#E2 RTN
310 A=4:GSB@C:A=0:X=T:Y=U:GSB@C
320 BEEP 9:WAIT20:X=P:Y=Q:GSB@C
330 L=L-1-(L=2&&SCR(15,12)=#E6)
340 BEEP 6:S=#E2:RTN
350 @C:LC X,Y:?STR$(C+A+2,2)
360 LC X,Y-1:?STR$(C+A,2):RTN

SAVE 1

LRUN 0

COMMENT

Kidspod運営チーム
Kidspod運営チーム2021/01/08 10:31:19

こんなゲームがあったのですね。先読みがものすごく要求されて、とても面白い! グラフィックや問題など、見事にIchigoJamに落とし込んでいて見事です!