VOICE TYPE みて・きいて・さがして・おぼえよう/Kidspod;

2019/09/19 18:45:38

GOOD!1
PLAY!0
VIEW1226

: イチゴジャムおじさん

VOICE TYPE みて・きいて・さがして・おぼえよう

Ichigo-iceを装着しろ、これでIchigoJamの能力が跳ね上がるぞ！
こいつ……しゃべるぞ。

アルファベットを未習のこどもを対象としたタイプ練習です。
画面にＡ～Ｚの文字が表示して、読み上げます。
キーの位置を探して、入力しましょう。
速度を目的にしていないので、音声の再生が終わってから次に進むようになっています。

30 Q="ASDFJKL"
30 Q="ASDGHFJKL"
30 Q="QWERTYUIOP"
30 Q="ZXCVBNM"
練習する文字を調整することができます。

アルファベットを覚えることが目的なので、まずは二本指打法から。
アルファベットを覚えたら、タッチタイプの練習に進みましょう。

プログラムをみる　で　Ichigo-iceなど詳しい説明のページにリンク

フルアーマーIchigoJam ブレッドボードに載せて、CN5で接続してみました。
SDAをジャンパー線を基板の下で接続しています。

10 'VOICE TYPE
20 VIDEO 3:CLS:?"VOICE TYPE"
30 Q="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
40 L=LEN(Q)
50 C=INKEY():IFC=0CONT
60 VIDEO 7:CLS
70 @L:M=PEEK(Q+RND(L))
80 @R:LC0,1:?CHR$(12);CHR$(M)
90 C=M:GSB@W:LC1,1:?">"
100 C=INKEY():IFC<>0CONT
110 @K:C=INKEY():IFC=0CONT
120 IFC=10VIDEO1:END
130 LC2,1:?CHR$(C):GSB@W
140 LC1,1
150 IFC=M?"=":S="#J":GSB@V:GOTO@L
160 ?"x":S="#K":GSB@V:GOTO@R
170 @W:S=0
180 IFC=65S="e'-"
190 IFC=66S="bi'-"
200 IFC=67S="si'-"
210 IFC=68S="de'-"
220 IFC=69S="i'-"
230 IFC=70S="e'fu"
240 IFC=71S="zi'-"
250 IFC=72S="e'ichi"
260 IFC=73S="a'i"
270 IFC=74S="je'-"
280 IFC=75S="ke'-"
290 IFC=76S="e'ru"
300 IFC=77S="e+mu"
310 IFC=78S="e+nu"
320 IFC=79S="o'-"
330 IFC=80S="pi'-"
340 IFC=81S="kyu'-"
350 IFC=82S="a'-ru"
360 IFC=83S="e'su"
370 IFC=84S="thi+-"
380 IFC=85S="yu'-"
390 IFC=86S="bu'i"
400 IFC=87S="da'buryu"
410 IFC=88S="e'kusu"
420 IFC=89S="wa'i"
430 IFC=90S="zwi'-"
440 IFS=0RTN
450 @V:U=I2CW(46,S,LEN(S))&I2CW(46,13)
460 U=I2CR(46,#910,1):IFPEEK(#910)<>62WAIT1:CONT
470 RTN

: Kidspod運営チーム2019/10/10 16:47:29
出た！　Ichigo-ice！　なるほど、これなら音声とタイピングの組み合わせがいけますね。IchigoJam+音声で広がるプログラムの世界。これから先が楽しみです。