イチゴジャム2048/Kidspod;

2019/07/29 12:08:30

GOOD!1
PLAY!3
VIEW1576

: YUNGLE

イチゴジャム2048

■２０４８
元はGabriele Cirulli氏が１９歳の時に腕試しでJavascriptで作ったシンプルな数字パズルゲームです。

■操作
移動：↑↓←→

■ゲーム内容
空いたマスに２が現れます。上下左右に数字をずらし、同じ数字が重なれば合算されます。できるだけ大きな数字を目指しましょう。
キーを押した時に動かせる数字がなければゲームオーバーです。

■改造ポイント
元は４x４マスですが３x３にしています。4x4に戻す改造がやりやすいと思います。

100 '2048 for ichigojam
110 'CLS:CLV:LET[0],8,4,2:X=3:Y=3:A=X*Y-1
120 CLS:VIDEO3:CLV:X=3:Y=3:A=X*Y-1
130 FOR I=0 TO 8
140  POKE #700+I,PEEK(#32*8+I)^#FF
150 NEXT
160 P=RND(A):[P]=2
170 FOR I=0 TO A
180  LC I%X*5,I/Y*Y+2
190  IF I=P ?CHR$(#E0); ELSE ?[I];
200  ? "   "
210 NEXT
220 LC0,0:?"SCORE ";S 
230 K=INKEY():IF K=0 GOTO230
240 CLK:FOR I=0 TO A
250  IF I%X=0 N=I
260  M=(K=28)*I+(K=29)*(A+1+~I)+(K=30)*(I%Y*Y+I/X)+(K=31)*(A+1+~(I%X*X+I/Y))
270  FOR L=I TO N STEP -1
280   J=(K=28)*L+(K=29)*(A+1+~L)+(K=30)*(L%X*X+L/Y)+(K=31)*(A+1+~(L%X*X+L/Y))
290   IF J=M GOTO 320
300   IF [J]=0 [J]=[M]:[M]=0
310   IF [J]=[M] [J]=[J]<<1:[M]=0:Z=0:S=S+[J]
320  NEXT:N=I
330 NEXT
340 I=0
350 IF [I]=0 GOTO 380
360 I=I+1:IF I<=A GOTO 350
370 LC0,Y*Y:?"GAME OVER":END
380 P=RND(A+1):IF [P]>0 GOTO 380 ELSE [P]=2
390 GOTO 170

: Kidspod運営チーム2019/08/13 17:38:57
いまや古典といっていいThrees!の模倣パズルですね。IchigoJam版になっても、やはり中毒性がすさまじいです……。本家のThrees!も素晴らしいゲームなので、ぜひ。