• IchigoJam

NEW

10 'PUNCH-PCG
20 POKE#700,#18,#18,#18,#18,#18,#18,#18,#18
30 POKE#708,#18,#18,#18,#18,#1F,#F,#0,#0
40 POKE#710,#18,#18,#18,#18,#F8,#F0,#0,#0
50 POKE#718,#0,#0,#F,#1F,#18,#18,#18,#18
60 POKE#720,#0,#0,#F0,#F8,#18,#18,#18,#18
70 POKE#728,#3C,#42,#81,#81,#81,#81,#42,#3C
80 POKE#730,#3C,#7E,#FF,#FF,#FF,#FF,#7E,#3C
90 POKE#738,#3C,#7E,#FF,#55,#AA,#FF,#7E,#3C
100 POKE#740,#3C,#42,#81,#81,#81,#81,#42,#3C
110 LRUNFILE()+1

SAVE 0

NEW

10 'PUNCH
20 VIDEO 3:CLS
30 A=6:B=6:C=4:E=0:F=0
40 @LP
50 A=A-BTN(LEFT)*(A>4)+BTN(RIGHT)*(A<8)
60 LCA-2,C+2:?" ~E6 ~E6 ";
70 LCA-2,C+3:?" ~E1~E6~E2 ";
80 B=B+RND(3)-1
90 IFB<4B=4
100 IFB>8B=8
110 LCB-2,C  :?" ~E3~E6~E4 ";
120 LCB-2,C+1:?" ~E6 ~E6 ";
130 K=INKEY()
140 IFK=90:R=0:GSB@PA
150 IFK=88:R=2:GSB@PA
160 K=RND(5)
170 IFK=0:R=0:GSB@PB
180 IFK=4:R=2:GSB@PB
190 WAIT 10
200 LC5,0:?E;"-";F
210 GOTO @LP
220 @PA:BEEP
230 LCA-1+R,C+2:?"~E0";
240 LCA-1+R,C+1:D=SCR()
250 IFD=ASC("~E6")?"~E7";:ELSE?"~E6";
260 LCA-1+R,C:D=SCR()
270 IFD=ASC("~E6")?"~E5";:BEEP20:E=E+1
280 WAIT10
290 LCA-1+R,C+1:D=SCR()
300 IFD=ASC("~E7")?"~E6";:ELSE?" ";
310 LCA-1+R,C+2:?"~E6";
320 @Z:K=INKEY():IFK<>0GOTO@Z
330 RTN
340 @PB:BEEP
350 LCB-1+R,C+1:?"~E0";
360 LCB-1+R,C+2:D=SCR()
370 IFD=ASC("~E6")?"~E7";:ELSE?"~E6";
380 LCB-1+R,C+3:D=SCR()
390 IFD=ASC("~E6")?"~E5";:BEEP20:F=F+1
400 WAIT10
410 LCB-1+R,C+2:D=SCR()
420 IFD=ASC("~E7")?"~E6";:ELSE?" ";
430 LCB-1+R,C+1:?"~E6";
440 RTN

SAVE 1

LRUN0

Pagetop