特盛り！いちごショート/Kidspod;

2018/10/28 00:15:13

GOOD!1
PLAY!2
VIEW1159

: あべのぶひで

特盛り！いちごショート

ここは街一番のケーキ屋さんです。
看板メニューは特盛りいちごショートです！

落ちてくるいちごを、ケーキでキャッチしてください。
どんどんいちごがくっついていきます。
一番上まで積み上げられたら、ゲームクリアです。
10個落としてしまうと、ゲームオーバーです。

操作は左右キー、再ゲームはエンターキーです。
大きいものを動かしてみたくて作りました。
ネタ的なゲームになるかと思ったのですが、予想に反してちゃんとしたゲームになったと思います。

ゲームクリアは、案外難しいですよ！

--------
20200116 IchigoJam Basic 1.3.0以降のスピードにあわせて更新しました。
バージョン1.2.3でプレイするときは行番号140の「:WAIT-100」を取り除いてください

10 'TOKUMORI ICHIGO SHORT
20 CLS:CLV:CLT
30 A=0:B=2:X=15:E=#E5
40 PLAY"T220C8.R8C4D2C2F2E1"
50 LOCATE X,22:PRINT CHR$(1,1,1):LOCATE X,23:PRINT CHR$(2,2,2);
60 Z=RND(28)+2:V=0:T=0
70 M=-BTN(LEFT)*(X+A>0)+BTN(RIGHT)*(X+B<30):X=X+M
80 LOCATE Z,V:PRINT CHR$(T);
90 COPY#91E,#91F,-31:SCROLL 4-(M=1)*3-(M=-1)
100 LOCATE 0,0:PRINT"ICHIGO:";G;"  MISS:";D
110 IF TICK()<180 THEN GOTO 70
120 V=V+1:IF V>23 THEN BEEP 200,20:D=D+1:GOTO 60
130 T=SCR(Z,V):S=SCR(Z,V+1)+T:P=Z+(S>0)*M
140 LOCATE P,V:PRINT CHR$(#FF);:WAIT-100
150 IF D=10 THEN LOCATE P,V:PRINT CHR$(0);:Y="GAME OVER":GOTO 210
160 IF S=0 THEN GOTO 70
170 IF V=1 THEN PLAY"T200C+8.R16C+4<C2>A2G2F4E4D1":WAIT 240:Y="CLEAR!":E=#E7:GOTO 210
180 IF P-X<A THEN A=P-X
190 IF P-X>B THEN B=P-X
200 PLAY"T900N5N3N6N4N3":G=G+1:GOTO 60
210 WAIT 60:CLK:LOCATE 23,0:PRINT STR$(Y)
220 PLAY"T200F8.R16F4E-2C2D2C1"
230 C=#920+RND(122)*6:F=PEEK(C):POKE C,F*(F>0)-F*(F=E)+E*(F=0)*(RND(5)=0):IF INKEY()=10 THEN RUN ELSE CONT

: Kidspod運営チーム2018/12/13 17:55:17
イチゴをもりもり積み上げられていくショートケーキが、なんか面白いですね。積んだイチゴの分移動範囲が狭くなったり、詰み方次第で遠くのイチゴを取りやすくなったりと、ゲームとしても面白いです！　簡単にクリアできると思っていたら、意外と戦略性があって、うなりました。