通常版　地底探検/Kidspod;

2018/08/06 23:15:35

GOOD!3
PLAY!4
VIEW1297

: あべのぶひで

通常版　地底探検

ワンライン地底探検が意外と楽しかったので、
キャラクタ、音、ゲームオーバー処理などを省略せずに作りました。

ルールはワンライン地底探検と同じです。
左右キーで自分を動かして、床に乗りながら地下へ降りてください。
床がなければ落ちますが、落ちている最中も移動できます。

床はせり上がってきます。自分が一番上に行ってしまうか、床に乗れずに一番下に落ちてしまうとゲームオーバーです。
スペースキーで再ゲームです。

新要素として、40メートル降りるごとに、スピードが速くなるようになっています。

Ichigojam

5 'ChiteiTanken
10 CLS:CLV
20 X=15:Y=1:I=8:Q=18:L=7
30 I=I+1:BEEP Q,3:WAIT L
40 R=R+1:IF R%4=0 THEN Q=Q-1
50 IF R=16 THEN R=0:Q=RND(24)+10
60 LOCATE RND(31),22:PRINT CHR$(6)
70 IF I<9 THEN GOTO 110
80 SCROLL 0:I=0:S=S+1:Y=Y-1
90 LOCATE 0,0:PRINT S;"m"
100 LOCATE 19,0:PRINT "ChiteiTanken"
110 M=BTN(RIGHT)*(X<30)-BTN(LEFT)*(X>0)
120 LOCATE X,Y:PRINT CHR$(0)
130 IF SCR(X,Y+1)=0 THEN Y=Y+1
140 IF SCR(X+M,Y)=0 THEN X=X+M
150 LOCATE X,Y:PRINT CHR$(#ED)
160 IF S%40=0 AND I=0 THEN BEEP 5,40:VIDEO 2:WAIT 40:VIDEO 1:L=L-1
170 IF Y>0 AND Y<22 THEN GOTO 30
180 WAIT 60:PLAY "O2B>AC"
190 LOCATE 12,10:PRINT "GAME OVER"
200 IF BTN(SPACE) THEN GOTO 10 ELSE CONT

: Kidspod運営チーム2018/08/28 20:42:47
豪華になって再登場！　ワンライン版も面白かったので嬉しいです。そして40メートルルールがとてもいいですね！　80メートルから明確にスピードの違いが分かって、どんどんテンポと難易度が上がっていき、楽しいです。

通常版 地底探検

通常版　地底探検