ＢｉｒｄＦｌｙＰａｎｃａｋｅ版/Kidspod;

2016/11/26 13:17:13

GOOD!2
PLAY!2
VIEW1537

: palboon

ＢｉｒｄＦｌｙＰａｎｃａｋｅ版

黄色い鳥を飛ばして降ってくるいちごを食べてください
なにも押さないと左右どちらかに進みつつ下に落ちていきます。
はスペースキーで上昇
Ｆキーで方向転換
ドクロにぶつかるとゲームオーバーです。
ドクロをよけて何個食べられるかな？
ゲームオーバーで画面が止まったら↓キーでｉｃｈｉｇｏｊａｍ画面にもどります。

10 'FLYNGbIRD
20 UART1:CLV:X=8:Y=3:V=-1:?"PC RESET":?"PC VIDEO 1":VIDEO0:?"PC SPRITE START 01"
30 FORI=0TO1:?CHR$(128,6,8,I,I*7,0):?CHR$(128,5,7,I,#A6):[I]=20:[I+2]=15:NEXT
40 @IN
60 IFP=15Y=Y+1:P=0
80 IFP%10=0X=X+V
90 IFX<0X=19
100 IFX>19X=0
110 K=INKEY()
120 IFK=32IFY>0:U=U+1
130 IFK=70V=-V
140 IFU>3Y=Y-1:X=X+V:U=0:BEEP80
160 IFX=[1]ANDY=[3]S=S+1:BEEP:[1]=20:?CHR$(128,5,7,0,#A6+S/10):?CHR$(128,5,7,1,#A6+S%10)
170 IFK=0P=P+1
180 IFY=0U=0
185 IFY<7IFX<>[0]ORY<>[2]GOTO@OUT
186 PLAY"T600CRCR2CRF1"
187 @GOV
188 IFBTN(DOWN)VIDEO1:?"PC VIDEO 0":ENDELSEGOTO@GOV
190 @OUT
200 ?CHR$(128,6,8,2,X*4,Y*6):?CHR$(128,5,16,2,(V=-1)):?CHR$(128,5,7,2,#2D+U%2)
210 FORI=0TO1
220 IF[I]=20[I]=RND(20):[I+2]=0
230 IF[I+2]>6[I]=20:GOTO@WED
240 IFRND(20)=0[I+2]=[I+2]+1
250 ?CHR$(128,5,7,3+I,#3E-I*32):?CHR$(128,6,8,3+I,[I]*4,[I+2]*6)
260 @WED
270 NEXT
280 GOTO@IN

: Kidspod運営チーム2016/11/28 21:30:54
ちょうどいい高さを飛ぶのが難しくて、つい熱中してしまいます。PanCakeだとどのアイテムを取るべきかすぐに分かっていいですね！

ＢｉｒｄＦｌｙ Ｐａｎｃａｋｅ版

ＢｉｒｄＦｌｙＰａｎｃａｋｅ版