Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2020/06/20 17:22:52

MixJuice GET URL : kidspod.club/mj/976

Hollow Seeker

でこぼこの地面の上に主人公がいます。上からでこぼこの天井が迫ってきますが、ところどころ隙間ができるので、潰されないようにうまく逃げ込んでください。果たして何回成功できるでしょうか?

RUN するといきなりゲームが始まります。カーソルキーで主人公を左右に移動させてください。段差は気にせず移動できます。
主人公が天井に潰されるとゲームオーバーとなり、プログラムが終了します。再挑戦する場合はもう一度 RUN してください。

110行目で C に代入している文字列は、スペース4つの後にAltキーとシフトキーを押しながら A,D,7,D,E,5,E,B と入力します。

  • 1
  • 2
  • 1
  • 2

SOURCE CODE

100 '=== Hollow Seeker by OBONO
110 CLV:CLK:C="    (#8A)(#8D)(#87)(#8D)(#8E)(#85)(#8E)(#8B)"
120 '--- WAVE START
130 S=4-R/5:P=6+S-R%5:P=P*P/8
140 R=R+1:S=S*(S>0):IF P<1 P=1
150 CLS:LC 0,21:?"Wave ";R
160 FOR I=0 TO 15:[I]=I<P:NEXT
170 FOR I=0 TO 15:J=RND(16)
180 Z=[I]:[I]=[J]:[J]=Z:NEXT
190 [16]=0:T=0:FOR I=1 TO 15
200 Z=[I]-[I-1]:Y=[I+15]
210 Y=Y+RND(5-ABS(Z)*2)-(Z<1)*2
220 [I+16]=Y:IF T<Y T=Y
230 NEXT:FOR I=0 TO 15
240 Y=[I+16]+20-T:[I+16]=Y
250 FOR J=Y TO 20:LC I*2,J
260 ?CHR$(3,3):NEXT:NEXT
270 X=7:A=8:GSB 420
280 '--- MAIN LOOP
290 FOR W=0 TO 19:FOR I=0 TO S
300 V=(BTN(29)-BTN(28))*(W<18)
310 IF V=0 GOTO 350
320 A=0:GSB 420:X=X+V
330 X=X+(X<0)-(X>15)
340 A=6+V*2:GSB 420
350 WAIT (5-(V!=0))*(I<S):NEXT
360 FOR I=0 TO 15
370 Y=[I+16]-[I]*2-20+W
380 IF Y>=0 LC I*2,Y:?CHR$(3,3)
390 NEXT:BEEP 16+W:NEXT
400 IF [X] WAIT 120:GOTO 130
410 LC 8,21:?"Game Over":END
420 '--- DRAW PLAYER
430 Y=[X+16]-2
440 LC X*2,Y+1:?STR$(C+A+2,2)
450 LC X*2,Y:?STR$(C+A,2):RTN

COMMENT

Kidspod運営チーム
Kidspod運営チーム2020/06/22 10:11:07

天井と地面のパターンを読んで、すぐに隙間のできる部分を判断しなくちゃいけない……。スリリングでいいゲームですね。