Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2020/06/15 07:00:13

MixJuice GET URL : kidspod.club/mj/974

t/i

t/i

デルタドライブ

 道からはずれないように進む縦スクロールゲームです。よくあるタイプのゲームですが、自機の向きを変えてコースを曲がるのが特徴です。IchigoJamのバージョン1.4以降用です。

【遊び方】
 画面下の方に表示される三角が自機(いちおう車のつもり)です。画面上の方から道が現れて強制スクロールで進みます。カーソルキーの左右で自機の方向を変えます。自機は向いている方向に進みます。進むにつれてだんだんスピードアップします。道の両側は壁になっていて、ぶつかるとゲームオーバーです。Enterキーで再スタートです。

【ご注意】
 このゲームは画面がチカチカするので、明るい場所で画面からなるべく離れて遊んで下さい。

【その他】
 自機は強制スクロールについて行くために斜め移動の時は速く移動しますがご了承下さい。また、自機と壁のヒットが納得いかない時もあるかと思いますがお許し下さい。

(2020/6/17・追記)
 プログラムの330行目にある「SCROLL2」を1つ削除してスクロールを1回にすると、ちょっと違ったゲームが楽しめます。

  • No registered tag exist.
  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

10 'Drive
20 VIDEO1:CLS:CLV:Z=10:O=1:X=32:Y=36:H=12:U=6:S=9
30 FORI=0TO23:[I*2]=COS((I+12)*15)*20/256:[I*2+1]=SIN((I+12)*15)*20/256:NEXT
40 FORI=48TO63:[I]=#101:NEXT
100 '
110 Q=0:P=RND(24)+8:N=RND(3)+1
200 '
210 COPY#8A0,#860,32:COPY#8A0+Z,#880,12:COPY#900,#8A0,32
220 U=(U+24)%24:R=(U+9)%24:L=(U+15)%24
230 A=X+[U*2]/4:B=Y+[U*2+1]/4:C=X+[R*2]/4:D=Y+[R*2+1]/4
240 E=X+[L*2]/4:F=Y+[L*2+1]/4:V=X+[U*2]/6:W=Y+[U*2+1]/6
250 IF(POINT(A,B)=1)|(POINT(C,D)=1)|(POINT(E,F)=1)|(POINT(V,W)=1) G=1
260 DRAWA,B,C,D:DRAWC,D,E,F:DRAWE,F,A,B
270 IF G=1 GOTO500
280 H=H+(BTN(29)=1)*(H<22)-(BTN(28)=1)*(H>2):U=H/2
290 IF Z>=20 O=-1 ELSE IF Z<=0 O=1
300 Q=(Q+1)%N:IF Q=0 Z=Z+O
310 DRAWA,B,C,D,0:DRAWC,D,E,F,0:DRAWE,F,A,B,0
320 X=X+[U*2]/5:Y=Y+[U*2+1]/5
330 SCROLL2:SCROLL2:M=M+1:Y=Y+4:IF Y>36 Y=Y-4
340 LC0,23:?M;"m";:IF(M%50=0)&(S>0) S=S-1:BEEPS+2,10
350 WAITS
360 P=P-1:IF P=0 GOTO100 ELSE GOTO200
500 '
510 LC12,10:?"Game Over":BEEP20,20
520 IF INKEY()=10 RUN ELSE CONT

COMMENT

Kidspod運営チーム
Kidspod運営チーム2020/06/22 09:53:38

慣性が重要になってくるゲームですね。とっさに方向を変えようとしても間に合わず、ちゃんと先を読まないとすぐにぶつかってしまうところが面白い!