Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2020/04/18 20:24:50

MixJuice GET URL : kidspod.club/mj/957

ナイト ハードラー

300メートルハードル走のゲームです。3D(?)です。
スペースキーとカーソルキーの右を交互に押すと走ります。
エンターキーでジャンプです。ハードルを飛び越えてください。
ジャンプしている最中はスペースキー・カーソルキーの右を押してもスピードアップしません。
再ゲームはエンターキーです。
ハードルに引っかかると、スピードダウンです。

300メートル走りきるとゴールです。
タイムが30秒以内だと「GOOD!」の文字が出ます。挑戦者求む!
IchgoJam1.4用です。

  • 1
  • 2
  • 3
  • 4
  • 5
  • 1
  • 2
  • 3
  • 4
  • 5

SOURCE CODE

10 'NightHurdler
20 CLS:CLV:X=33
30 POKE #980,#91:COPY #981,#980,31
40 LC 10,8:?"Night Hurdler":LC 14,11:?"READY":BEEP 9,90:WAIT 90
50 LC 14,11:?"START":BEEP 2,40:WAIT 40:CLT
60 POKE #900+RND(128),#90*(!RND(20) OR U>13)
70 U=U-!!U:Y=(Y+S+3700)%3700:P=P+S/10:IF Y<300 AND P>5500 Y=0
80 IF Y>3100 AND U=0 THEN S=S/2:Y=0:FOR I=0 TO 7:SCROLL I%2*2:BEEP 100,9:WAIT 5:NEXT
90 C=Y/100:A=X-C/2:B=X+C/2:D=C+C/3:E=10+V*2
100 LC 0,5+V:?CHR$(12)
110 DRAW A,C+E+!!U,B,C+E+!!U
120 DRAW A,C+E+!!U,A,D+E:DRAW B,C+E+!!U,B,D+E
130 W=INKEY():CLK:IF W=10 AND U=0 THEN U=18
140 IF U>11 THEN V=V+1:SCROLL 2
150 IF U>0 AND U<8 THEN V=V-1:SCROLL 0
160 T=TICK():LC0,V+3:? T/60;".";T%60*10/6;"s";:LC 28,V+3:? P/20;"m";
170 S=S-!!S:BEEP 25+U
180 K=BTN(32)*2+BTN(29)
190 IF (K=1 OR K=2) AND L<>K AND U=0 THEN L=K:S=S+5+(S<20)*15
200 IF P<6000 THEN GOTO 60
210 LC 15,10:?"GOAL":BEEP 5,60:WAIT 60:CLK
220 IF T<1800 THEN LC 15,13:?"GOOD!"
230 IF INKEY()=10 THEN RUN ELSE CONT

COMMENT

Kidspod運営チーム
Kidspod運営チーム2020/04/27 18:14:08

なかなかタイミングがシビアで楽しいです。奥から迫ってくるハードルは、ファミコン・スーファミ時代を思い起こしますね。私はこれを3Dと呼びたい!