Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/10/28 00:15:13

MixJuice GET URL : kidspod.club/mj/657

特盛り!いちごショート

ここは街一番のケーキ屋さんです。
看板メニューは特盛りいちごショートです!

落ちてくるいちごを、ケーキでキャッチしてください。
どんどんいちごがくっついていきます。
一番上まで積み上げられたら、ゲームクリアです。
10個落としてしまうと、ゲームオーバーです。

操作は左右キー、再ゲームはエンターキーです。
大きいものを動かしてみたくて作りました。
ネタ的なゲームになるかと思ったのですが、予想に反してちゃんとしたゲームになったと思います。

ゲームクリアは、案外難しいですよ!

  • 1
  • 2
  • 3
  • 4
  • 5
  • 1
  • 2
  • 3
  • 4
  • 5

SOURCE CODE

10 'TOKUMORI ICHIGO SHORT
20 CLS:CLV:CLT
30 A=0:B=2:X=15:E=#E5
40 PLAY"T220C8.R8C4D2C2F2E1"
50 LOCATE X,22:PRINT CHR$(1,1,1):LOCATE X,23:PRINT CHR$(2,2,2);
60 Z=RND(28)+2:V=0:T=0
70 M=-BTN(LEFT)*(X+A>0)+BTN(RIGHT)*(X+B<30):X=X+M
80 LOCATE Z,V:PRINT CHR$(T);
90 SCROLL 4-(M=1)*3-(M=-1)
100 LOCATE 0,0:PRINT"ICHIGO:";G;"  MISS:";D;" "
110 IF TICK()<180 THEN GOTO 70
120 V=V+1:IF V>23 THEN BEEP 200,20:D=D+1:GOTO 60
130 T=SCR(Z,V):S=SCR(Z,V+1)+T:P=Z+(S>0)*M
140 LOCATE P,V:PRINT CHR$(#FF);
150 IF D=10 THEN LOCATE P,V:PRINT CHR$(0);:Y="GAME OVER":GOTO 210
160 IF S=0 THEN GOTO 70
170 IF V=1 THEN PLAY"T200C+8.R16C+4<C2>A2G2F4E4D1":WAIT 240:Y="CLEAR!":E=#E7:GOTO 210
180 IF P-X<A THEN A=P-X
190 IF P-X>B THEN B=P-X
200 PLAY"T900N5N3N6N4N3":G=G+1:GOTO 60
210 WAIT 60:CLK:LOCATE 23,0:PRINT STR$(Y)
220 PLAY"T220F8.R16F4E-2C2D2C1"
230 C=#920+RND(122)*6:F=PEEK(C):POKE C,F*(F>0)-F*(F=E)+E*(F=0)*(RND(5)=0):IF INKEY()=10 THEN RUN ELSE CONT

COMMENT