Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/09/24 14:38:00

MixJuice GET URL : kidspod.club/mj/567

赤いガラスのような小さい石

いつからこんなことをしているのだろう。
ぼくの手にあるのは、赤いガラスのような小さい石だ。
何かに共鳴するかのように光りだす。
でもきっと探しているものは墓の下。
墓をあばいて良いのだろうか。

ストーリーです。 ポエムではありません!

ここは荒れた墓場です。亡霊が1匹います。
亡霊につかまらないように、墓の下にある探し物を見つけてください。

あなたは赤いガラスのような小さい石を持っています。
IchigoJamについているやつです。
探し物の近くに来るほど、点滅します。
これを頼りに探し物のある墓(十字マーク)を踏んでください。
探し物が入っていない墓を踏むと呪いでしばらく動けなくなります。

亡霊は壁をすりぬけて、追いかけてきます。
亡霊は壁や霧などに隠れて見えなくなりますが、あなたに近づくと音がします。近くなるほど高い音になります。(音ありでプレイしてください。)

穴に落ちると、少しの間動けません。

操作は上下左右キーです。再ゲームはエンターキーです。

ちょっと怖いゲームです。

(9/26 更新: ステージクリア時の亡霊の位置と、次のステージの墓の位置が同じである場合に、墓の表示が消えるバグを修正しました。)

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

5 'SS
10 CLS:CLV:A=#900:X=16:Z=1:V=22
20 S=S+1:T=-3:C=#93:PLAY"F8E8D8C+8CGF"
30 FOR I=0 TO 30:IF I%10=0 POKE A+RND(736),#C
40 LC RND(16)*2,RND(22):?CHR$(6,28,31,6);
50 POKE A+RND(733),4,4,4:NEXT
60 FOR I=0 TO 2:G=RND(32):H=RND(22)+1:POKE A+G+H*32,#93:NEXT
70 LC 8,23:?"Seek Something:";S;:WAIT115
80 E=(B=29)*(X<31)-(B=28)*(X>0):F=(B=31)*(Y<22)-(B=30)*(Y>0)
90 IF E*2+F=0 OR SCR(X+E,Y+F)=6 GOTO130
100 POKE A+X+Y*32,D:X=X+E:Y=Y+F:D=SCR(X,Y)
110 IF D=#C T=-3:VIDEO0
120 IF D=#93 T=-15
130 POKE A+X+Y*32,#F9
140 M=X-Z:N=Y-V:P=M*M+N*N:IF P<40 BEEP1+P/9*50,9
150 M=X-G:N=Y-H:P=M*M+N*N:LED RND(P/3+2)=0
160 IF TICK()<30 AND T=0 GOTO200
170 CLT:R=RND(2):K=((X>Z)*2-1)*(X<>Z)*(R=0):L=((Y>V)*2-1)*(Y<>V)*(R=1)
180 POKE A+Z+V*32,C:Z=Z+K:V=V+L:C=SCR(Z,V)
190 IF C=0 OR T<0 POKE A+Z+V*32,#EC
200 IF X=Z AND Y=V GOTO240
210 B=INKEY():CLK:IF X=G AND Y=H VIDEO2:GOTO20
220 IF T=0 GOTO80
230 BEEP250:WAIT15:T=T+1:VIDEO0:WAIT3:VIDEO1:GOTO130
240 VIDEO1:WAIT150:BEEP200,99
250 POKE A+RND(736),0:LC12,10:?"GAME OVER":IF INKEY()=10 RUN ELSE CONT

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/10/02 22:34:32

なにこれ。天才ですか? 演出がもう、全部すごい! 音の演出が緊迫感出てますし、LEDのヒントを見ていても亡霊が来ているということが分かる! 落とし穴やお墓の演出も、ものすごく焦りますし、ゲームオーバーもホラー映画のエンディングのようです! ものを探すということが、こんなにも面白いとは!