Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/09/02 21:34:55

MixJuice GET URL : kidspod.club/mj/560

ムーンレスキュー

月面に取り残された遭難者を救命艇で救助してください。

まず、画面下部の遭難者に向かってください。救命艇に遭難者を乗せると、画面上部の母船のハッチが開きますので、母船にドッキングしてください。

操作は左右キーで移動、スペースキーでエンジン噴射です。
操作に慣れるまで、少し難しいかもしれません。

左右に漂う隕石や、流星に当たるとゲームオーバーです。流星はときどき残骸を残していきます。
救命艇は月面に着陸できません。遭難者を乗せたらエンジン噴射して、月面にぶつからないようにしてください。
母船本体にぶつかったり、母船より上昇してもNGです。
再ゲームはエンターキーです。

1980年のゲーム「ルナレスキュー」のオマージュ的に作りました。残念ながら実物をやったことはないのですが、随分違うものになっていると思います。

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

10 'MR
20 CLS:CLV:V=1:Z=11:X=15:POKE#1002,0
30 ?"MOON RESCUE"
40 POKE#BE0,#8D:COPY#BE1,#BE0,31
50 Y=3:C=300:G=60:A=#E3:L=L+1
60 LC 24,0:?"TURN:";L:PLAY"O5D8G8A8B":WAIT60
70 POKE#BA7+RND(19),#F9
80 BEEP160,2:LC X,Y:? CHR$(0)
90 U=(U+3)*(U<11):IF U%9 GOTO150
100 B=BTN(32):G=(G+8*(G<60))-B*25*(G>-45):C=C+G:Y=C/100
110 X=X+(X<29)*BTN(29)-(X>1)*BTN(28)
120 Z=Z+V:IF Z<1 OR Z>23 V=-V
130 POKE#920+Z,0,#9F,#8B,#EB,#87,#9E,0
140 POKE#940+Z,0,#83,A,A,A,#83,0
150 COPY#9A0+U*32,#9A1+U*32,31
160 COPY#9DF+U*32,#9DE+U*32,-31
170 R=RND(2):POKE #9A2+(R=0)*28+(U+R)*32,#16*(RND(24-L/2)=0)
180 IF N>0 BEEP N:LC M,N:? CHR$(0):N=(N+1)*(N<19):M=(M+Q)*(N>0):LC M,N-(N=0):? CHR$(#F4) ELSE M=R*29+1:N=(RND(6)+1)*(RND(99-L*3)=0):Q=(R=0)*2-1
190 S=SCR(X,Y)+(Y<2)
200 LC X,Y:? CHR$(#F0);
210 IF B=1 BEEP250:W=#920+X+Y*32:IF PEEK(W)=0 POKE W,#56:WAIT2:POKE W,0
220 IF S=12 GOTO50
230 IF S=249 BEEP2:WAIT9:A=12:S=0
240 IF S=0 GOTO80
250 FOR I=0 TO 19:LC X,Y:? CHR$(I%2*#F4);:WAIT5:NEXT:LC 12,9:?"GAME OVER":CLK
260 IF INKEY()=10 THEN RUN ELSE CONT

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/10/02 22:24:41

エンジンのバランスが楽しいですね。上手く制御しないと隕石や流星と激突、月面にも激突、母船にも激突! この絶妙なバランスを保ち続けるのがクセになります。