Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/08/22 22:17:20

MixJuice GET URL : kidspod.club/mj/545

ハングマン

定番ゲームのハングマンです。

画面に表示される文字数の英単語を当ててください。

英単語は中学1年レベルです。行番号30を書き換えると変更できます。(文字列の一番最初にスペースを1つ入れておいてください。)

6回間違うとゲームオーバーです。スペースキーでリトライできます。

IchigoJamのハングマンを見たことがなかったので作りました。

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

10 'HANGMAN
20 CLS:CLV:VIDEO3
30 A=" DOG CAT PENCIL BOOK BOY GIRL TREE EGG MOTHER MILK APPLE BREAD LEMON TOMORROW HAPPY HONEST RIGHT SOUTH NIGHT TOWN WALL PARK TEACHER GATE DAUGHTER SCHOOL HOSPITAL LIBRARY"
40 FOR I=0 TO LEN(A):[C]=I:C=C+(PEEK(A+I)=32):NEXT
50 LET [90],10,#E8,11,#8F,21,#1A,01,#19,22,#1A,02,#19
60 CLS:H=0:L=0:N=0
70 ? CHR$(#8C,#8C,#8C,#8C,#8C)
80 ? CHR$(#8A,25,0,#7C,10,#8A,10,#8A,10,#8A,10,#8A,10,#8A,10,#8E,#8C)
90 FOR I=0 TO 10:SCROLL 1:WAIT 12:NEXT
100 LC 0,0:?"HANGMAN"
110 P=P+1:?"GAME:";P
120 R=RND(C):F=A+[R]+1:G=[R+1]-[R]-1
130 POKE #971,#5F:COPY #972,#971,G-1
140 K=INKEY():IF K=0 THEN CONT
150 H=H+1:LC H,10:? CHR$(K)
160 M=0:FOR I=0 TO G
170 IF PEEK(F+I)=K AND SCR(1+I,7)=#5F THEN LC 1+I,7:? CHR$(K):L=L+1:M=1:BEEP 5
180 NEXT
190 IF L=G THEN BEEP 2:LC 4,4:?"GOOD!":WAIT 180:GOTO 60
200 IF M=1 THEN GOTO 140
210 B=90+N*2:LC 13+[B]/10,2+[B]%10:? CHR$([B+1]):BEEP 250,10
220 N=N+1:IF N<6 THEN GOTO 140
230 LC 0,4:?"GAME OVER"
240 LC 1,8:? STR$(F,G)
250 IF INKEY()=32 THEN RUN ELSE CONT

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/08/31 18:55:19

ハングマンというのですね。運と洞察、語彙力を問われるかなり面白いゲームです。演出面が相変わらず素晴らしい! 黒地に白文字だと、このハングマンの見た目がかなり不気味ですね……。