Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/08/19 17:31:47

MixJuice GET URL : kidspod.club/mj/544

スシリズム

音ゲー的なゲームです。
すしが流れてきますので全部取ってください。すしネタはちょっとカオスです。

ルールはシンプルです。画面右のキャラクタのところで、タイミングよく何かキーを押してください。
皿の真ん中でゲットすると1点、端だと0.5点です。
皿がないところでキーを押したり、皿が取れないとマイナス1点です。
皿は全部で100皿流れてきます。
80点以上取れたらクリアです。

最初にレベルを入力します。レベル1がいちばん簡単です。
音ゲーと言っても、音とキー入力タイミングの連動性はありません。

スピードを調節するとき通常はWAITを使いますが、音ゲーは即時性が大事なので、行番号200から220のところでTICK()を使ってキー入力が判断できる状態で時間調節をしています。

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

10 'Sushi Rhythm
20 CLV:CLS
30 ?"LEVEL(1-9)";:INPUT T
40 T=10-T:A=#9A:B=#91:C=#9B
50 POKE #BFF,#F0-T/2:COPY #BFE,#BFF,-770
60 LC 8,1:?"Sushi Rhythm Lv";10-T;
70 PLAY"$T240 O2G+8A8B8A8 B8A8O1C8O2G+8 A8<D8C8O1E8 O2C8E8F8O1D8":WAIT120
80 POKE #960,0:COPY #961,#960,607
90 POKE #A59,#ED
100 CLT:I=I+1
110 IF (I%3=0)*RND(2)=0 THEN GOTO 160
120 D=D+1:IF D>110 THEN GOTO 310
130 IF D>100 THEN BEEP100:GOTO 160
140 POKE #A02,#E4+RND(28)
150 POKE #A21,A,B,C
160 COPY #A1F,#A1E,-31:COPY #A3F,#A3E,-31
170 COPY #9A0,#9A4,29
180 F=F+(SCR(30,9)=A)
190 S=SCR(25,9)
200 IF INKEY()>0 THEN GOTO 230 
210 IF TICK()>T THEN GOTO 100 
220 GOTO 200
230 P=(S=A)+(S=B)*2+(S=C)*3
240 E="Bad GOODEXCELLENTNICE"
250 COPY #9B4,E+P*4+(P=3)*5,4+(P=2)*5
260 IF P=0 THEN F=F+1:GOTO 200
270 POKE #A18+I%3,0:POKE #A37+I%3,0,0,0
280 POKE #BA1+L/10*3-L%10*32,A,B,C
290 L=L+1:N=N+1+(P=2)
300 GOTO 200
310 PLAY"T240O2C8F8O1E8O2E+2"
320 LC 12,5:?"POINT:";N/2
330 LC 12,6:?"MISS :";F
340 G=N/2-F:LC 12,8:?"TOTAL:";G
350 LC 12,10:IF G>79 THEN ?"CLEAR!" ELSE ?"Fail"

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/08/31 18:54:59

音ゲーライクな連打ゲーですね。流れてくるものが寿司というにはヘンテコで楽しいです。レベル9の難易度はとんでもないものでした……。