Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/07/15 14:22:54

MixJuice GET URL : kidspod.club/mj/519

メニメニゾンビ

ゾンビの群れに取り囲まれてしまった。
こうなったら爆破攻撃で撃退するしかない!
連鎖爆破で一網打尽だ!

アメリカ映画によくありそうな「ゾンビに囲まれた。」です。
ゾンビにつかまらないように、ゾンビを爆破してください。
ゾンビは良く燃える(?)ので、爆発にゾンビを巻き込むと連鎖式に爆発(誘爆)します。

矢印キーで移動。スペースキーを押し続けると、カウントダウン後に自分の周りを爆破します。
連鎖式にゾンビを爆破すると、1体目は1点、2体目は2点・・・というように、加算されるスコアが上がっていきます。
ゾンビを爆破した数に応じて、ゾンビの動きが速くなり、自分の動きが遅くなっていきます。このため、あまり連鎖しない爆破を繰り返すと、ゾンビが早くなるだけで、スコアが稼げません。一度にたくさんのゾンビを爆破しましょう。
ゾンビは自分を追ってきます。この習性を使うと、群れになったところを爆破できます。

スペースキーを押しながら移動できますので、うまく使ってください。
ゲーム初番では自分の動きが速いので、自分からゾンビに突っ込んで行きがちです。注意!
画面最上部と最下部のゾンビは爆破できません。
壁も爆破できます。
ゾンビは100体います。
画面左上の「Zombie」は爆破したゾンビの総数です。

今回はソースが長くなりがちで、1KBに収めるのに苦労しました。
音ありでプレイがおすすめです。

(2019/06/06 IchigoJam BASIC 1.2.3と1.3.1で動作確認済)

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

5 'MMZ
10 CLS:CLV
20 COPY #780,#30,8
30 X=15:Y=12:G=#FA
40 FOR I=0 TO 25:POKE #991+RND(500),#F0,#F0,#F0,0,0:NEXT
50 FOR I=0 TO 99:GSB350:NEXT
60 A=10
70 M=BTN(29)*(X<30)-BTN(28)*(X>1)
80 N=BTN(31)*(Y<20)-BTN(30)*(Y>4)
90 U=SCR(X+M,Y+N):BEEP 9,2
100 POKE #900+X+Y*32,0
110 IF U<>#F0 THEN X=X+M:Y=Y+N
120 IF BTN(32) THEN A=A-1:E=#30+A:BEEPA ELSE A=10:E=#ED
130 POKE #900+X+Y*32,E
140 IF U=G THEN LC 11,10:? "GAME OVER":PLAY "BG":END
150 FOR I=0 TO D/20
160 C=(C+1)*(C<99)
170 Z=[C]/100:V=[C]%100
180 M=(X>Z)-(X<Z):N=(Y>V)-(Y<V)
190 POKE #900+Z+V*32,0
200 IF SCR(Z+M,V+N)<#F0 THEN Z=Z+M:V=V+N:[C]=Z*100+V
210 POKE #900+Z+V*32,G
220 NEXT
230 IF A>0 GOTO70
240 Q=X:R=Y:GSB310:T=0
250 F=0:FOR I=0 TO 99
260 Q=[I]/100:R=[I]%100
270 IF (SCR(Q,R)<>G)*(R>1)*(R<23) THEN T=T+1:D=D+1:F=1:S=S+T:BEEP 1+(30-T)*(T<30):WAIT5:GSB310:GSB350
280 BEEP 190:NEXT
290 IF F=1 GOTO250
300 GOTO60
310 B=#8DF+Q+R*32:POKE B,4,4,4
320 POKE B+32,4,#F4,4
330 POKE B+64,4,4,4
340 LC 0,0:?"Zombie:";D;" Score:";S:RTN
350 [I]=(RND(29)+2)*100+22*(RND(2))+1:RTN

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/07/31 21:47:10

自分の移動とカウントダウンのスピード管理、ゾンビの移動スピードや集まり具合、地形を考えたゾンビの誘導……。すごい! 一級の戦術ゲームですね! 音もうまくできていて、誘爆したときの爽快さも楽しい! タイトルも好きです。