Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2018/06/19 22:46:23

MixJuice GET URL : kidspod.club/mj/501

Rainy Run

雨にあたらないように、向こうの屋根まで走るんだ!

使うキーは、左右キーです。
雨にあたるとゲームオーバー。何かキーを押すと再ゲームです。

ichigojamのメモリコピー機能が面白いので、作ってみました。

(2018/06/21 更新)
メモリコピーの効率がよくなるように修正しました。
スピードが速くなりすぎたのでWAITをいれました。
雨音(?)っぽい音をいれました。

(2019/06/06 IchigoJam BASIC 1.2.3と1.3.1で動作確認済)

  • 1
  • 2
  • 1
  • 2

SOURCE CODE

10 CLS:L=1:X=1
20 FOR I=0 TO 30:LOCATE I,22:PRINT CHR$(#04);:NEXT
30 LOCATE 0,20:PRINT CHR$(#9F,#9E)
40 LOCATE 29,20:PRINT CHR$(#9F,#9E)
50 LOCATE 0,0:PRINT "Rainy Run"
60 LOCATE 23,23:PRINT "Level ";L;
70 FOR I=0 TO 4
80 LOCATE RND(28),1
90 IF RND(20)<L THEN PRINT " ";CHR$(#2F);" ":PLAY "L64O5E" ELSE PRINT "   "
100 NEXT
110 WAIT 6
120 COPY #BA2,#B83,26
130 COPY #B82,#B63,27
140 COPY #B7F,#B60,-576
160 IF SCR(X,21)=#2F THEN GOTO 230
170 IF X=29 THEN GOTO 220
180 K=INKEY():CLK
190 X=X-(K=LEFT AND X>2)+(K=RIGHT AND X<29)
200 LOCATE X-1,21:PRINT " ";CHR$(#FB)
210 GOTO 70
220 LOCATE X,21:PRINT" ":X=1:L=L+1:PLAY "L16AO5A":GOTO 60
230 LOCATE 12,10:PRINT "GAME OVER"
240 LOCATE X,21:PRINT CHR$(#F9)
250 PLAY "L16AO2A":WAIT 60:CLK
260 IF INKEY()=0 THEN GOTO 260 ELSE GOTO 10

COMMENT

Kidspod運営チーム
Kidspod運営チーム2018/06/29 19:06:37

斜めにふってくるというのがいいですね。どこに落ちてくるかが難しくなって、特にゴールに近づくほど、雨が出現してから地面に落ちるまでが短くなりますから、後ろに下がる方がよけやすい……いいバランスです! 雨音もステキですね。