Enjoy programming more!
Kidspod is a post site which supports young programmers.
First step to join us.
Register as a member
For members

2019/05/02 23:05:48

MixJuice GET URL : kidspod.club/mj/815

ANAGMA B型(I2C EEPROM SAVE)

これは、通常のANAGMA B型に、暗号文を保存する機能を追加したものです。

注意)必ず、I2CのEEPROM (CAT24M01)を差した状態で使ってください。

使い方の変更点は、
・Alt+C で暗号文の保存。Alt+V で暗号文の読み込み。
・最初の画面で、保存した暗号文の閲覧(REVIEW)を追加。
です。

後はhttp://kidspod.club/program/default.html?id=814と同じ。

(基本的な詳しい使い方はhttp://kidspod.club/program/default.html?id=167)

  • 1
  • 2
  • 3
  • 4
  • 1
  • 2
  • 3
  • 4

SOURCE CODE

NEW

1 'ANAGMA-B(SETUP-2.0) [REVIEW]
5 CLS:CLV:B=0:F=FILE()
10 LC10,11:?"<<ANAGMA-B>>":WAIT60
15 CLS:LC10,1:?"MODE SELECT":LC11,7:?"ENCODE: 1":LC11,9:?"DECODE: 2":LC11,11:?"REVIEW: 3
20 K=INKEY()
21 IFK=49Q=1:GOTO60
22 IFK=50Q=2:GOTO60
23 IFK=51GOTO500
25 GOTO20
60 CLS:CLK:W=0:LC5,2:?"INPUT 12 DIGIT CODEKEY"
65 LC10,4:?"<4 DIGIT x3>"
70 FORG=0TO2
75 LC12,12+2*G:INPUTN:IFN>9999ORN<1000GOTO50
80 A=4*G
85 GSB400
90 NEXT
100 CLS:LC8,1:?"SYSTEM SELECT":LC0,7:FILESF+1,F+1:LC29,7:?": 1":LC0,9:FILESF+2,F+2:LC29,9:?": 2":'LC0,11:FILESF+3,F+3:LC29,11:?": 3"
105 K=INKEY():CLK
110 IFK=49LRUNF+1
115 IFK=50LRUNF+2
120 'IFK=51LRUNF+3
125 GOTO105
400 [A]=N/1000:[A+1]=(N%1000)/100:[A+2]=((N%1000)%100)/10:[A+3]=((N%1000)%100)%10:RTN
500 LED1:WAIT60:CLS:I=0:O=I2CR(#51,#8DC,2,#920,256):LED0
505 K=INKEY():CLK
510 IFK=10CLS:GOTO15
515 GOTO505

SAVE1

NEW

1 'ANAGMA-B(SYSTEM1-1.1)
2 'I2C EEPROM(CAT24M01) only!
5 CLS:F=FILE():I=0:W=0
10 LC0,0:?"INPUT:":LC0,12:?"OUTPUT:"
15 K=INKEY():CLK:IFK=0GOTO15
16 IFW>11W=0
17 IFW<0W=11
18 IFK=236&&Q=1GOTO200
19 IFK=255&&Q=2GOTO300
20 IFK=8ORK=10GOTO35
25 IFK<27ORK>223GOTO15
30 IFK=8GOTO55
35 IFI=256GOTO45
40 'IFK=10POKE#920+I,10:POKE#AA0+I,10:GOTO100
45 IFK=127LRUNF-1
50 IFK<>8GOTO80
55 IFI<=0I=0:GOTO15
60 IFW>-1&&I>-1I=I-1:W=W-1:POKE#920+I,0:POKE#AA0+I,0:GOTO15
65 IFW<0W=11:GOTO60
70 IFI<=0I=0:GOTO15
80 IFI=256GOTO15
85 POKE#920+I,K
90 '
95 POKE#AA0+I,K+(Q=1)*[W]-(Q=2)*[W]
100 I=I+1:W=W+1
105 IFW>11W=0
106 IFW<0W=11
110 GOTO15
200 FORI=0TO1:W=I2CW(#51,#8DC,2,#AA0+I*128,256):LED1:NEXT
205 WAIT60:LED0:CLS:CLV:LC10,12:?"[-COPIED-]":WAIT60:LRUNFILE()-2
300 LED1:WAIT60:I=0:O=I2CR(#51,#8DC,2,#920,256):LED0
305 I=0:W=0
310 FORI=0TO320:K=PEEK(#920+I)
315 IFK=0GOTO15
320 'IFK=10POKE#AA0+I,K:GOTO330
325 POKE#AA0+I,K+(Q=1)*[W]-(Q=2)*[W]
330 W=W+1
335 IFW>11W=0
340 NEXT
345 GOTO15

SAVE2

NEW

1 'ANAGMA-B(KEY MAKER-1.0)
5 CLS:F=FILE()
10 [0]=RND(8)+1:[1]=RND(8)+1:[2]=RND(8)+1:[3]=RND(8)+1
15 [4]=RND(8)+1:[5]=RND(8)+1:[6]=RND(8)+1:[7]=RND(8)+1
25 [8]=RND(8)+1:[9]=RND(8)+1:[10]=RND(8)+1:[11]=RND(8)+1
28 LC9,3:?"SAVE TO PAPER"
30 LC13,9:?[0];[1];[2];[3]
35 LC13,11:?[4];[5];[6];[7]
40 LC13,13:?[8];[9];[10];[11]
50 LC8,23:?"ONE MORE: Delete
55 LC8,20:?"      GO: Enter
100 K=INKEY():CLK
105 IFK=10LRUNF-1
106 IFK=127RUN
110 GOTO100

SAVE3

COMMENT

Kidspod運営チーム
Kidspod運営チーム2019/06/07 17:19:12

保存機能! これは暗号文でやりとりしたいときには必須ですね。これでより一層、ANAGMAの使い方が広がりそうです。