プログラミングをもっと楽しく!
Kidspod;はこどものプログラマーを
応援するための投稿サイトです。
はじめての人はこちらから
新規メンバー登録
メンバーの人はこちらから

2017/04/16 17:49:33

MixJuice GET URL : kidspod.club/mj/189

7並べ

7並べです

プレイヤーとコンピュータ3人の全4人で戦います。
マークを選ぶところで99を入力するとパスできます。
パスは3回までです。

■勝利条件
・プレイヤーが最初に上がる

■敗北条件
・コンピュータが最初に上がる
・プレイヤーが4回パスをする

  • 1
  • 1

SOURCE CODE

1 CLV:FORI=0TO38
2 R=RND(52):IF[R]GOTO2
3 [R]=1<<(I/13):NEXT:FORI=0TO51:IF[I]=0[I]=8
4 NEXT:[6]=16:[19]=16:[32]=16:[45]=16
5 @M:P=1:GSB24:?:INPUT"マーク:1-4 P:99? ",M
6 IFM=99Z=Z+1:[53]=Z:IFZ=4GOTO32
7 IFM=99GOTO10
8 INPUT"スウジ:1-13? ",N:IFM<1ORM>4ORN<1ORN>13GOTO@M
9 E=(M-1)*13+N-1:Q=0:GSB@K:IFQ=0GOTO@M
10 GSB@C:GSB@C:GSB@C:GOTO@M
11 @C:P=P*2:R=RND(52):E=R
12 E=E+1:IFE=52E=0
13 IFE=RGOTO16
14 Q=0:GSB@K:IFQ=0GOTO12
15 RTN
16 [52+P]=[52+P]+1:IF[52+P]<4RTN
17 FORI=0TO51:IF[I]&P[I]=16
18 NEXT:RTN
19 @K:F=E:IF[E]&P=0RTN
20 D=(E%13<6)-(E%13>6)
21 F=F+D:IFF%13=6[E]=16:Q=1:RTN
22 IF[F]=16GOTO21
23 RTN
24 CLS:[58]=0:[59]=0:[61]=0:[65]=0:FORI=0TO51:IFI%13=0?:LC0,I/13:?CHR$(#E4+I/13);" ";
25 IF[I]&16?I%13+1;" ";ELSE?"  ";
26 [57+[I]]=[57+[I]]+1:NEXT:I=1:J=0:LC4,5:?"カード パス":?"アナタ ";
27 ?[57+I];"   ";[52+I]:IF[57+I]=0AND[52+I]<4?"アガリ!!":IFJ=0ENDELSEGOTO32
28 I=I*2:J=J+1:IFI<>16?"COM";J;" ";:GOTO27
29 FORI=0TO51:IFI%13=0?:?I/13+1;":";CHR$(#E4+I/13);" ";
30 IF[I]&1?I%13+1;" ";
31 NEXT:RTN
32 ?"アナタノマケ"

COMMENT